【方案一】刪除指定路徑下指定天數(shù)之前（以文件的最后修改日期為準）的文件：BAT + REG + VBS
代碼如下:
@echo off
::演示：刪除指定路徑下指定天數(shù)之前（以文件的最后修改日期為準）的文件。
::如果演示結(jié)果無誤，把del前面的echo去掉，即可實現(xiàn)真正刪除。
::本例調(diào)用了臨時VBS代碼進行日期計算
::本例為兼容不同的日期格式，調(diào)用reg命令（XP系統(tǒng)自帶）統(tǒng)一設(shè)置日期格式，
::處理完畢之后再把日期格式恢復成原來的狀態(tài)。
rem 指定待刪除文件的存放路徑
set SrcDir=C:/Test/BatHome
rem 指定天數(shù)
set DaysAgo=1
for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate') do (
set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
>"%temp%/DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%/DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%/DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%/DstDate.vbs"') do (
set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
for /r "%SrcDir%" %%a in (*.*) do (
if "%%~ta" leq "%DstDate%" (
if exist "%%a" (
echo del /f /q "%%a"
)
)
)
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
【方案二】刪除指定路徑下指定天數(shù)之前（以文件的最后修改日期為準）的文件：BAT + REG + Ritchie Lawrence 日期函數(shù)
代碼如下:
@echo off
::演示：刪除指定路徑下指定天數(shù)之前（以文件的最后修改日期為準）的文件。
::如果演示結(jié)果無誤，把del前面的echo去掉，即可實現(xiàn)真正刪除。
::本例調(diào)用了 Ritchie Lawrence 的日期函數(shù)進行日期計算
::日期轉(zhuǎn)換的核心算法請參考http://bbs.bathome.cn/thread-3056-1-1.html
::本例為兼容不同的日期格式，調(diào)用reg命令（XP系統(tǒng)自帶）統(tǒng)一設(shè)置日期格式，
::處理完畢之后再把日期格式恢復成原來的狀態(tài)。
rem 指定待刪除文件的存放路徑
set SrcDir=C:/Test/BatHome
rem 指定天數(shù)
set DaysAgo=1
for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate') do (
set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%
for /r "%SrcDir%" %%a in (*.*) do (
if "%%~ta" leq "%DstDate%" (
if exist "%%a" (
echo del /f /q "%%a"
)
)
)
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof
:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF
:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
【方案三】刪除指定路徑下指定天數(shù)之前（以文件的最后修改日期為準）的文件：BAT + VBS
代碼如下:
@echo off
::演示：刪除指定路徑下指定天數(shù)之前（以文件的最后修改日期為準）的文件。
::如果演示結(jié)果無誤，把del前面的echo去掉，即可實現(xiàn)真正刪除。
::本例調(diào)用了臨時VBS代碼進行日期計算，并統(tǒng)一設(shè)置系統(tǒng)日期格式，處理完畢
::之后再把日期格式恢復成原來的狀態(tài)。擺脫了對reg命令（XP系統(tǒng)自帶）的依賴。
rem 指定待刪除文件的存放路徑
set SrcDir=C:/Test/BatHome
rem 指定天數(shù)
set DaysAgo=1
>"%temp%/BackupDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%/BackupDate.vbs" echo WScript.Echo WshShell.RegRead ("HKEY_CURRENT_USER/Control Panel/International/sShortDate")
for /f %%a in ('cscript /nologo "%temp%/BackupDate.vbs"') do (
set "RegDateOld=%%a"
)
>"%temp%/UnifyDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%/UnifyDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER/Control Panel/International/sShortDate", "yyyy-M-d", "REG_SZ"
cscript /nologo "%temp%/UnifyDate.vbs"
>"%temp%/DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%/DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%/DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%/DstDate.vbs"') do (
set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
for /r "%SrcDir%" %%a in (*.*) do (
if "%%~ta" leq "%DstDate%" (
if exist "%%a" (
echo del /f /q "%%a"
)
)
)
>"%temp%/RecoverDate.vbs" echo Set WshShell = WScript.CreateObject("WScript.Shell")
>>"%temp%/RecoverDate.vbs" echo WshShell.RegWrite "HKEY_CURRENT_USER/Control Panel/International/sShortDate", "%RegDateOld%", "REG_SZ"
cscript /nologo "%temp%/RecoverDate.vbs"
pause
【方案四】刪除指定路徑下指定天數(shù)之前（以文件的創(chuàng)建日期為準）的文件：BAT + REG + Ritchie Lawrence 日期函數(shù)
代碼如下:
@echo off
::演示：刪除指定路徑下指定天數(shù)之前（以文件的創(chuàng)建日期為準）的文件。
::如果演示結(jié)果無誤，把del前面的echo去掉，即可實現(xiàn)真正刪除。
::本例調(diào)用了 Ritchie Lawrence 的日期函數(shù)進行日期計算
::日期轉(zhuǎn)換的核心算法請參考http://bbs.bathome.cn/thread-3056-1-1.html
::本例為兼容不同的日期格式，調(diào)用reg命令（XP系統(tǒng)自帶）統(tǒng)一設(shè)置日期格式，
::處理完畢之后再把日期格式恢復成原來的狀態(tài)。
rem 指定待刪除文件的存放路徑
set SrcDir=C:/Test/BatHome
rem 指定天數(shù)
set DaysAgo=1
for /f "skip=2 delims=" %%a in ('reg query "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate') do (
set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%
for /f "delims=/" %%a in ('dir /s /b /a-d "%SrcDir%"') do (
call :CompareTime "%%a"
)
reg add "HKEY_CURRENT_USER/Control Panel/International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
goto :eof
:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF
:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
:CompareTime
for /f "skip=5 tokens=1-2 delims= " %%h in ('dir /a-d /tc %1') do (
if "%%h" leq "%DstDate%" (
if exist %1 (
echo del /a /f /q %1
)
)
goto :eof
)
【方案五】刪除指定路徑下指定天數(shù)之前（以文件的修改日期為準）的文件：forfiles
代碼如下:
@echo off
::演示：刪除指定路徑下指定天數(shù)之前（以文件的最后修改日期為準）的文件。
::如果演示結(jié)果無誤，把del前面的echo去掉，即可實現(xiàn)真正刪除。
::本例需要Win2003/Vista/Win7系統(tǒng)自帶的forfiles命令的支持
rem 指定待刪除文件的存放路徑
set SrcDir=C:/Test/BatHome
rem 指定天數(shù)
set DaysAgo=1
forfiles /p %SrcDir% /s /m *.* /d -%DaysAgo% /c "cmd /c echo del /f /q /a @path"
pause
【方案六】刪除指定路徑下指定天數(shù)之前（以文件名中包含的日期字符串為準）的文件：字符串截取
代碼如下:
@echo off
::演示：刪除指定路徑下指定天數(shù)之前（以文件名中包含的日期字符串為準）的文件。
::如果演示結(jié)果無誤，把del前面的echo去掉，即可實現(xiàn)真正刪除。
::本例假設(shè)文件名中包含的日期字符串（比如：bak-2009-12-25.log）
rem 指定待刪除文件的存放路徑
set SrcDir=C:/Test/BatHome
rem 指定天數(shù)
set DaysAgo=1
>"%temp%/DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%/DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%/DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%/DstDate.vbs"') do (
set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
setlocal enabledelayedexpansion
for /r "%SrcDir%" %%a in (*.*) do (
set "FileDate=%%~na"
set "FileDate=!FileDate:~4,10!"
if "!FileDate!" leq "%DstDate%" (
if exist "%%a" (
echo del /f /q "%%a"
)
)
)
endlocal
pause
更多信息請查看IT技術(shù)專欄
公眾號
事業(yè)單位
當前位置：
公考類
招聘類
各類考試