寫過PHP的都知道，其有個extract()非常方便，可以便捷的將字典轉(zhuǎn)換為變量，當(dāng)然到ASP中則要受限很多，特別是VBScript腳本，本文敘述的就是一種轉(zhuǎn)換的思路，可以實現(xiàn)類似的功能。

下面我就直接提供ASP版本的extract代碼吧：

代碼如下:

'

' ASP/VBScript Dictionary extract

' Author: WangYe

' For more information please visit

'    

' This code is distributed under the BSD license

'

' collection 集合或者字典，可以通過For Each訪問的

'            Request.Form 或者 Request.QueryString

' specified  指定必須存在的屬性，假如該屬性不存在，將自動創(chuàng)建一個

' prefix     每個屬性的前綴修飾

' callback   對于集合或者字典的每個元素(key-value)的值進(jìn)行函數(shù)調(diào)用

'            函數(shù)原型：

'            Function filter(key, value)

'                filter = value

'            End If

'            最終值將以該函數(shù)返回的值為準(zhǔn)

'

Function extract(collection, ByVal specified, prefix, callback)

    Dim VarName, VarValue, DynObj, searchKey

    specified = "," & Replace(specified, " ", "") & ","

    Set DynObj = New DynamicObject

    For Each key In collection

        searchKey = "," & key & ","

        If InStr(1, specified, searchKey, 1)>0 Then

            specified = Replace(specified, searchKey, "")

            If Left(specified, 1) <> "," Then

                specified = "," & specified

            End If

            If Right(specified, 1) <> "," Then

                specified = specified & ","

            End If

        End If

        VarName = prefix & key

        VarValue = collection(key)

        If callback<>"" Then

            VarValue = GetRef(callback)(key, VarValue)

        End If

        DynObj.add VarName, VarValue, PROPERTY_ACCESS_READONLY

 Next

    specified_array = Split(specified, ",")

    Dim i

    For i = LBound(specified_array) To UBound(specified_array)

        If specified_array(i)<>"" Then

            DynObj.add prefix & specified_array(i), "", _

  PROPERTY_ACCESS_READONLY

        End If

    Next

    Set extract = DynObj.GetObject()

End Function

再介紹下使用方法：

代碼如下:

Dim query

Set query = extract(Request.QueryString, "name,id", "", "")

    Response.Write query.name

    Response.Write query.id

Set query = Nothing

訪問包含上述代碼的ASP頁面，在QueryString（就是URL問號后面的）包含name=wangye你將看到頁面輸出”wangye”，包含id=12的時候，將輸出”12″，當(dāng)然你也可以同時指定兩項。

你可能發(fā)現(xiàn)當(dāng)你Response.Write輸出name和id之外key的時候，程序報錯了，因為指定的屬性不存在，當(dāng)你在查詢字符串包含這個key的時候，程序又正常了，因為有了這個key就自動建立了屬性，所以又可以直接Response.Write了，如何避免呢？

1. 通過extract()函數(shù)的specified參數(shù)，該參數(shù)是個以逗號隔開key的字符串，你可以看到剛才示例代碼中運用了這個特性，如果查詢字符串未包含相應(yīng)的key，但是你又使用了這個key，只要specified列表中有，就會自動建立值為空的屬性，所以就不會報錯啦。

2. 通過返回對象的hasattr_方法進(jìn)行使用前判斷，這個方法可以判斷extract()函數(shù)返回的對象是否存在相應(yīng)的屬性，比如代碼有：

代碼如下:

Dim query

Set query = extract(Request.QueryString, "name,id", "", "")

If query.hasattr_("job") Then

    Response.Write "Job : " & query.job

End If

Set query = Nothing

這里job并不在我們的specified列表中，但是不帶查詢字串的直接訪問程序沒有報錯，因為我們通過hasattr_在使用前進(jìn)行判斷是否存在此屬性。

3. 通過返回對象的getattr_方法進(jìn)行安全訪問，這個方法會在使用前判斷指定的屬性是否存在，如果不存在則用默認(rèn)值替代，詳細(xì)參考DynamicObject說明，比如代碼：

代碼如下：

Dim query

Set query = extract(Request.QueryString, "name,id", "", "")

    Response.Write "Job : " & query.getattr_("job", "No Job")

Set query = Nothing

最后再介紹下filter的使用，extract()函數(shù)的filter參數(shù)，指定的是另外一個函數(shù)名字符串，然后extract()將對每個值調(diào)用該函數(shù)進(jìn)行處理，比如過去有這樣的代碼：

代碼如下：

Dim name, job, id

name = Trim(Request.QueryString("name"))

job = Trim(Request.QueryString("job"))

id = CLng(Trim(Request.QueryString("id")))

可以看到，我們每一次都調(diào)用了Trim()函數(shù)，重復(fù)的寫多次很麻煩，而且以后如果要改變相應(yīng)功能還要一個一個替換，通過filter參數(shù)我們可以這樣寫：

'

' Function filter(key, value)

'   filter = Trim(value)

' End Function

'

Function filter(key, value)

    On Error Resume Next

    Select Case key

        Case "id" ' 判斷ID是否是數(shù)字

            If Not IsNumeric(value) Then

                Exit Function

            End If

            If CLng(value)<1 Then

                Exit Function

            End If

    End Select

    ' 最后記得讓函數(shù)返回值，該值在extract將被置為該返回值

    filter = Trim(value)

    If Err.Number<>0 Then

        filter = ""

    End If

End Function

Dim query

Set query = extract(Request.QueryString, "name,id,job", "", "filter")

    Response.Write query.name

    Response.Write query.job

    Response.Write query.id

Set query = Nothing

剛才我們是以Request.QueryString為例子的，當(dāng)然你也可以使用Request.Form來實現(xiàn)表單處理的更多功能，希望這篇文章能夠給你編寫ASP帶來方便:-)

更多信息請查看IT技術(shù)專欄