這個是腳本代碼[保存為etime.bat放在當前路徑下即可：

代碼如下:

:etime <begin_time> <end_time> <return>

rem 所測試任務的執(zhí)行時間不超過1天 // 骨瘦如柴版

setlocal&set be=%~1:%~2&set cc=(%%d-%%a)*360000+(1%%e-1%%b)*6000+1%%f-1%%c&set dy=-8640000

for /f delims=: tokens=1-6 %%a in (%be:.=%)do endlocal&set/a %3=%cc%,%3+=%dy%*(%3>>31)&exit/b

計算兩個時間點差的函數(shù)批處理etime

今天興趣大法思考了好多bat的問題，以至于通宵

在論壇逛看到有個求時間差的函數(shù)被打攪調用地方不少(大都是測試代碼執(zhí)行效率的)

代碼如下:

:time0

::計算時間差（封裝）

@echo off&setlocal&set /a n=0&rem code 隨風 @bbs.bathome.cn

for /f tokens=1-8 delims=.: %%a in (%~1:%~2) do (

set /a n+=10%%a%%100*360000+10%%b%%100*6000+10%%c%%100*100+10%%d%%100

set /a n-=10%%e%%100*360000+10%%f%%100*6000+10%%g%%100*100+10%%h%%100)

set /a s=n/360000,n=n%%360000,f=n/6000,n=n%%6000,m=n/100,n=n%%100

set ok=%s% 小時 %f% 分鐘 %m% 秒 %n% 毫秒

endlocal&set %~3=%ok:-=%&goto :eof

這個代碼的算法是統(tǒng)一找時間點凌晨0:00:00.00然后計算任何一個時間點到凌晨的時間差(單位跑秒)

然后任意兩個時間點求時間差就是他們相對凌晨時間點的時間數(shù)的差

對09這樣的非法8進制數(shù)的處理用到了一些技巧，還有兩個時間參數(shù)不分先后順序，可全可點，

但是這個代碼一行是可以省去的(既然是常被人掉用自然體積越小越好):

代碼如下:

@echo off&setlocal&set/a n=0&set s=+:%~1^&echo -:%~2

for /f tokens=1-5 delims=.: %%a in ('echo %s%') do (rem code 隨風 @bbs.bathome.cn

set/a n%%a=10%%b%%100*360000+10%%c%%100*6000+10%%d%%100*100+10%%e%%100)

set /a s=n/360000,n=n%%360000,f=n/6000,n=n%%6000,m=n/100,n=n%%100

set ok=%s% 小時 %f% 分鐘 %m% 秒 %n% 毫秒

endlocal&(if %3. equ . (echo %ok:-=%) else set %~3=%ok:-=%)&exit/b

再研究下，有更簡短的版本

這個代碼是我在cn-dos寫過的，今天再優(yōu)化了下更簡短

代碼的算法深入一層：

用hmsw(各字母代表一個兩位數(shù)字)表示標準時間

我們記他到凌晨的相對時間數(shù)為tx

tx=hmsw時間點-0:00:00.00時間點=h*3600*100+m*60*100+100*s+w

hmsw 8位10進制數(shù)表示的時間數(shù)(單位0.01秒)就是hmsw跑秒

hmsw=w+100*s+10000*m+1000000*h

hmsw-tx=640000*h+4000*m

所以tx=hmsw-(640000*h+4000*m)=hmsw-4000*(160*h+m)

那么tx_2-tx_1=hmsw_2-hmsw_1-4000*(160*(h_2-h_1)+(m_2-m_1))

對與09這樣的非法8進制數(shù)我們給他們每個前面加上1就可以保證是十進制數(shù)又能保證差值不變

對于非同一天的時間(這種情況較少，除非你在接近0晨時調用)我們把用8640000-去替換負號

再用set/a賦值

就是下面代碼用到的算法

tx_2-tx_1=hmsw_2-hmsw_1-4000*(160*(1h_2-1h_1)+(1m_2-1m_1))

代碼如下:

rem 兼容時間點跨天的情行，時間格式00:00:00.00 或者 0:00:00.00 皆可

:_difftime <begin_time> <end_time> [ret] //返回兩個時間點的差值(單位0.01秒)

setlocal enabledelayedexpansion&set b=0%1&set e=0%2&set c=1!e:~-11!-1!b:~-11!&set c=!c::=!

set/a c=%c:.=%-4000*(160*(1%e:~-11,-9%-1%b:~-11,-9%)+1%e:~-8,-6%-1%b:~-8,-6%)

endlocal & (if %3.==. (echo %c:-=8640000-%) else set/a %3=%c:-=8640000-%)&exit/b

給difftime前面加上_是為了表明不是臨時寫的子過程也為了以后連接庫函數(shù)標簽的唯一性

// 題外話：

對于子過程，若啟用了變量延遲，原則上三行都可以寫完，盡量寫緊湊些（因為沒人讀），但是對于算法，思路性的東西要能舍得筆墨，越詳細越好，我發(fā)現(xiàn)即使你的代碼寫得再好，不會有人全搬，都會小修改，你自己初寫代碼時不可能考慮到所有人使用的具體情況，自然沒人愿意很詳細看你的代碼，倒是你的思路為別人提供了一個方法，在此意義上函數(shù)庫的作用起到方法庫的作用